I’ve had this old Intempo 3D Headset hanging off the corner of my desk for at least seven years, and never bothered to do anything with it.

So, tonight, it finally annoyed me into action.

So, it is a lens based 3d thing that you slot your ‘phone into and it does “3d images”. Well yes, but only if the images are correctly formatted.

You can’t just show any old shite on your phone and expect it to give you 3D magic. It is nothing more that a modern day View-Master.

I’m not going for the 3D magic at the moment anyway. My mission was to take a square image, and bend it so that it would display properly in the headset.

And for once, despite my preference for Linux based solutions, I did it in a Windows Batch File, using ImageMagick (my Ubuntu server is currently offline, and I find the idea of WSL slightly sickening).

So, taking an image like this:

It resizes it, places it in the target image, Magick happens, and this is produced:

Note that this is formatted for a 1600×720 screen, and you will have to modify this to suit your own phone viewport, and possibly change the image offsets too.

But, in the spirit of niceness, here is the CONV23D.BAT file wot I made:

@echo off
REM Check if the input image filename is provided as a parameter
if "%~1"=="" (
echo Usage: conv23d.bat ^<image filename^>
exit /b 1
)

REM Get the input image filename and its base name
set "input_image=%~1"
for %%f in ("%input_image%") do (
set "filename=%%~nf"
set "extension=%%~xf"
)

REM Define the output filename with _3d appended
set "output_image=%filename%_3d%extension%"

REM Resize the input image to 650x650 pixels while keeping its color
magick "%input_image%" -resize 650x650 resized_image.png

REM Create a black canvas of 1600x720 (full color, black background)
magick -size 1600x720 xc:black canvas.png

REM Place the resized image at (150px across, 0px down) on the canvas
magick composite -colorspace sRGB -geometry +150+0 resized_image.png canvas.png canvas_with_image_1.png

REM Place the resized image again at (800px across, 0px down) on the canvas
magick composite -colorspace sRGB -geometry +800+0 resized_image.png canvas_with_image_1.png "%output_image%"

REM Clean up temporary files
del resized_image.png
del canvas.png
del canvas_with_image.png
del canvas_with_image_1.png

REM Output result
echo Created output image: %output_image%

Obviously this simple script doesn’t do any 3D processing or anything clever like that. Get someone cleverer than me to do that stuff.

Oh, also if you want to do an entire directory, the BATCH_CONV.BAT is your friend…

@echo off
REM Check if the directory argument is provided
if "%~1"=="" (
echo Please provide a directory.
exit /b 1
)

REM Check if the provided directory exists
if not exist "%~1" (
echo Directory %~1 does not exist.
exit /b 1
)

REM Loop through each .jpg file in the specified directory
for %%f in ("%~1\*.jpg") do (
REM Call the secondary batch file with the .jpg file as an argument
call conv23d.bat "%%f"
)

echo Done processing .jpg files.

 

I’m going to soldier on with this forgotten piece of junk, as I’m starting to find the whole idea of Stereoscopic photography interesting, and I may employ a Macro Lens to do 3D shots of Model Railways.